Armando Leopoldo Keller » AIR

De Monster Debugger – como utilizar

Armando Leopoldo Keller — Sat, 02 May 2009 21:11:48 +0000

0saves

Faz tempo que eu não posto nada, devido a falta de tempo , e de ideias sobre o que postar.
Hoje, resolvi postar sobre como utilizar o MonsterDebugger, o melhor debugger que eu ja vi para actionscript.

Primeiro, o que é esse MonsterDebugger ?
O MonsterDebugger ( http://demonsterdebugger.com/ ) é um debugger Open Source feito em AIR, que permite debugar aplicaçoes Actionscript (flash, flex, air …), não só dando trace, mas podendo editar as propriedades dos objetos em tempo real, e podendo executar os metodos dos objetos quando quiser. Alem de claro, dar trace nas coisas (se for algum array, xml, objeto … ele apresenta o conteudo em arvore, assim fica mais facil de debuggar).

Agora sim, vou mostrar como se usa ele.

1 – Instale o client:
Va em http://demonsterdebugger.com/ , pegue a versão mais recente do MonsterDebugger e instale ele no seu computador.

2 – Gere as classes necessarias:
Abra o client (instalado anteriormente) e va em File -> Export Client Class

3 – Se quiser pode gerar um exemplo (File -> Export example), ou pode tentar usar direto sem o exemplo.

Como dar um simples Trace:

1	MonsterDebugger.trace(this, o_que_é_para_ir_no_trace)

Como ativar o live application:

1 2	var _debugger:MonsterDebugger; _debugger = new MonsterDebugger(this);

A parte de utilizar o Client é bem intuitiva, caso alguem tenha duvidas de como utilizar, favor me avisar que eu coloco aqui detalhadamente como utilizar.

Lembrando que aceito sugestoes de posts, é só entrar em contato.

Classe para utilização de SQL em AIR (Flash, Flex)

Armando Leopoldo Keller — Sat, 05 Apr 2008 22:42:27 +0000

0saves

Save

Neste tutorial mostrarei como utilizar uma classe que eu criei para facilitar o uso de SQL em AIR (tanto para flash quanto para flex)
A classe é esta:

/*
################################################
#                                              #
#   Classe  : DB (com.alkeller.air.DB)         #
#   Autor   : Armando Leopoldo Keller          #
#   Versão  : 1.0                              #
#   Contato : alksk8@hotmail.com               #
#   Blog    : http://alkeller.wordpress.com    #
#   Documentaçao em breve no blog              #
#                                              #
################################################
------- Deixe os creditos na classe ----------
*/
package com.alkeller.air
{
	// Imports
	import flash.data.SQLResult;
	import flash.filesystem.File;
	import flash.data.SQLStatement;
	import flash.data.SQLConnection;
	import flash.events.SQLEvent;
	import flash.events.SQLErrorEvent;
	import flash.errors.SQLError;
 
	// Classe;
	public class DB
	{
		// Variaveis utilizadas;
		private static var conectado:Boolean = false;
		private static var dbFile:File
		private static var conn:SQLConnection
		private static var _sqlStatement:SQLStatement;
		private static var resultado:SQLResult;
		private static var retornoString:String;
		private static var retornoObjeto:Object;
 
		// Funçao Inicia :utilizada para conectar com o banco de dados;
		public static function Inicia(_nome:String):String
		{
			conn = new SQLConnection();
			dbFile = File.applicationStorageDirectory.resolvePath(String(_nome+".db"));
			try
			{
				conn.open(dbFile);
				conectado = true;
				trace("Conectado com "+_nome+".db");
				retornoString = "Conectado com "+_nome+".db";
			}
			catch (error:SQLError) 
			{
				conectado = false;
				retornoString = "Falha ao conectar: "+error.message+"\nDetalhes: "+error.details;
			}
			return retornoString;
		}
		// Funçao executeQuery: Utilizada para executar um comando SQL(verificar quais são aceitos pelo AIR);
		// Retorno: SQLResult --> http://livedocs.adobe.com/flash/9.0/ActionScriptLangRefV3/flash/data/SQLResult.html
		// ou  String de erro;
		public static function executeQuery(_sql:String):Object
		{
			if(conectado == true)
			{
				_sqlStatement = new SQLStatement();
				_sqlStatement.sqlConnection = conn;
				_sqlStatement.text = _sql;
				try
				{
					_sqlStatement.execute();
					resultado = _sqlStatement.getResult();
					retornoObjeto = resultado;
				}
				catch (error:SQLError)
				{
					retornoString = "Falha ao executar("+_sql+"): "+error.message+"\nDetalhes: "+error.details;
				}
				return retornoObjeto?retornoObjeto:retornoString;
			}
			else
			{
				return "Não conectado!";
			}
		}
	}
}

Classe para download: http://paginas.terra.com.br/lazer/alksk8/DB.as

Como utilizar:
1 – Importe a classe:

// OBS: Aqui é bom verificar se a classe esta no local certo com/alkeller/air/
import com.alkeller.air.*;
// ou
import com.alkeller.air.DB;

2 – Inicie o banco:

1	DB.Inicia("teste"); // sendo que teste é o nome do banco

3 – Se as tabelas não existirem, crie elas:

1	DB.executeQuery("CREATE TABLE IF NOT EXISTS testando (id INTEGER PRIMARY KEY AUTOINCREMENT,nome TEXT,sobrenome TEXT)");

4.1 – Execute as Querys que desejar, por exemplo inserir alguns dados:

1	DB.executeQuery("INSERT INTO testando (id,nome,sobrenome) VALUES (null,'ARMANDO LEOPOLDO','KELLER')");

4.2 – Exemplo de como buscar dados:

var obj:Object = DB.executeQuery("SELECT * FROM testando").data;
for(var i:uint=0; i < obj.length; i++)
{
	trace("linha: "+i);
	for(var j:Object in obj[i])
	{
		trace(j+": "+obj[i][j])
	}
}

Aproveitem a classe

Em breve colocarei aqui este tutorial em video.

NativeMenu em AIR (flash)

Armando Leopoldo Keller — Sun, 16 Mar 2008 21:04:42 +0000

0saves

Save

Olá, segue abaixo um exemplo comentado de como utilizar menus(como os da maioria dos softwares) em AIR, é um exemplo básico baseado em tutoriais da Adobe.

/*
Primeiro crie um arquivo novo(air)
crie um campo de texto com o tamanho que desejar
instancie o campo de texto como "texto" (sem as aspas)
cole o codigo a seguir no primeiro frame
*/
 
// importa	as classes necessarias
import flash.display.NativeMenu;
import flash.display.NativeMenuItem;
import flash.display.NativeWindow;
import flash.desktop.NativeApplication;
 
//declara os 2 items do menu
var Menu01:NativeMenuItem;
var Menu02:NativeMenuItem;
 
if (NativeWindow.supportsMenu)// Se o sistema operacional for windows
{
	stage.nativeWindow.menu = new NativeMenu(); //cria o menu
	stage.nativeWindow.menu.addEventListener(Event.SELECT, selecionouUmItem);//adiciona um evento de seleção no menu
	Menu01 = stage.nativeWindow.menu.addItem(new NativeMenuItem("Primeiro item"));//adiciona o primeiro item no menu
	Menu01.submenu = criaSubMenu(); // adiciona o submenu(que vai ser criado logo abaixo) ao primeiro item
	Menu02 = stage.nativeWindow.menu.addItem(new NativeMenuItem("Segundo item"));//adiciona o segundo item no menu
}
 
if (NativeApplication.supportsMenu)// se o sistema operacionall for mac
{
	Menu01 = NativeApplication.nativeApplication.menu.addItem(new NativeMenuItem("Primeiro item"));//adiciona o primeiro item no menu
	NativeApplication.nativeApplication.menu.addEventListener(Event.SELECT, selecionouUmItem);//adiciona um evento de seleção no menu
	Menu01.submenu = criaSubMenu(); // adiciona o submenu(que vai ser criado logo abaixo) ao primeiro item
	Menu02 = NativeApplication.nativeApplication.menu.addItem(new NativeMenuItem("Segundo item"));//adiciona o segundo item no menu
}
 
function criaSubMenu():NativeMenu
{
	var tmpMenu:NativeMenu = new NativeMenu(); // cria o submenu do primeiro item
	var MenuNovo:NativeMenuItem = tmpMenu.addItem(new NativeMenuItem("Novo"));//adiciona o item "Novo" ao submenu
	var MenuSalva:NativeMenuItem = tmpMenu.addItem(new NativeMenuItem("Salva"));//adiciona o item "Salva" ao submenu
	var MenuSair:NativeMenuItem = tmpMenu.addItem(new NativeMenuItem("Sair"));//adiciona o item "Sair" ao submenu
	return tmpMenu;
}
 
function selecionouUmItem(e:Event)
{
	texto.text = e.target.label // escreve o nome do item selecionado no campo de texto
}

Qualquer duvida é só postar que eu respondo.

Assim que sobrar algum tempo por aqui eu postarei um tutorial (bem detalhado) e com os exemplos, de como utilizar um banco de dados local com o AIR.